Search for untagged ways in overpass-turbo

Question

Is there a way to search for untagged ways that are not part of a multi-polygon relation using overpass-turbo.eu? I am trying to locate all ways in my county that were not tagged (i.e. untagged highways, untagged buildings, pools, etc.)

Answer 1

First of all, there's also a Geofabrik Tool available to find ways without tags, called OSM Inspector. The respective analysis can be found in the tagging view as ways without tags (just in case someone wonders, why overpass turbo comes into play for this).

Back to the question: Find all ways in a bbox and remove all ways with any tag will give you the desired result:

((way({{bbox}}); - way({{bbox}})[~"."~"."];);>;);
out meta;

Link to overpass turbo: http://overpass-turbo.eu/s/6WF

Edit: OP was actually looking for ways without tags, not belonging to relations (but didn't mention that in the first place). For this use case, please try the following:

(way({{bbox}}); - way({{bbox}})[~"."~"."];)->.w1;
rel(bw.w1);way(r)->.w2;
(.w1; - .w2;);
(._; >;);
out meta;

Overpass Turbo Link: http://overpass-turbo.eu/s/6WH

Since version 0.7.54 there's also the following option:

way({{bbox}})(if:count_tags()==0)->.w1;
rel(bw.w1);way(r)->.w2;
(.w1; - .w2;);
(._; >;);
out meta;