How to use union in area queries (QL/XML) with Overpass API/OpenStreetMaps?

Question

I am using area queries to find nodes with particular amenities Eg:-

[out:json]; 
area[name = "New York"]; 
node(area)[amenity=bar]; 
out; 

However the issue with this is that if I query the following:

[out:json]; 
area[name = "New York"]; 
(   
  node(area)[amenity=bar];
  node(area)[amenity=restaurant]; 
); 
out; 

The output includes only the first amenity, i.e. 'bar' even though there's a union. If I reverse the order to put 'restaurant' before 'bar' the output includes only restaurants. I also tried the same using XML syntax but in vain. Any ideas?

Answer 1

This can be easily fixed by storing the area in a named inputset (I use .a below) and referring to this inputset for both node statements:

[out:json]; 
area[name = "New York"]->.a; 
(   
  node(area.a)[amenity=bar];
  node(area.a)[amenity=restaurant]; 
); 
out; 

Link to Overpass turbo: http://overpass-turbo.eu/s/a2v

Some background information: In your example, (area) (short form for (area._)) refers to the default input set. An inputset is contains the nodes, ways, relations and areas, which are to be processed by the next statement.

Once the first node statement is processed, that default inputset in your query just contains nodes with [amenity=bar].

Important point here is, that the inputset no longer contains your New York area. The subsequent node statement doesn't have an area to work on anymore. Hence, you didn't get any restaurants in your query.

Answer 2

Not sure about the exact problem, but the basic syntax is right. For example via overpass turbo:

[out:json][timeout:25];
(
  node["amenity"="restaurant"]({{bbox}});
  node["amenity"="toilets"]({{bbox}});
);
out body;
>;
out skel qt;

Please be aware that Overpass is for training only. If you want to create an production workflow with global coverage, it's reocmmend to build your own toolchain with planet.osm, osmosis, ...