Concatenate points values in a field of a line

Question

I'd like to know how to concatenate points values (attribute data), using fields calculator of QGIS, putting this concatenation in a new field of the linear feature which connect some points of these.

For example, i'd like to get a new field called "name" in the linear layer, putting the concatenation of the field "type" of the points connected; from start point to the end point:

Any suggestions?

Answer 1

Try something like this in the field calculator in the lines layer

array_to_string(
    overlay_intersects(
        'layer',
        "type"
    ),
    ','
)

Replace layer with the layer name / id of the point layer.

Use this to return the data ordered by the position of the point in the line:

aggregate(
    layer:='Points layer name/id', -- set here the points layer name/id
    aggregate:='concatenate',
    expression:=to_string("type"), -- set here the field to be concatenated from points
    filter:=intersects(
        $geometry,
        geometry(@parent)
    ),
    order_by:=array_filter(
        array_foreach(
            generate_series(
                1,
                num_points(geometry(@parent))
            ),
            array(
                @element,
                point_n(
                    geometry(@parent),
                    @element
                )
            )
        ),
        intersects(
            $geometry,
            @element[1]
        )
    )[0][0],
    concatenator:=',' -- set here the concatenator
)

Result, red tags are the concatenated fields from points.