Overpass API: get "building" in area with landuse='x'

Question

I get regions with landuse=industrial with this query

[out:json];
area["name"="my_area"]->.searchArea;
(
  way["landuse"="industrial"](area.searchArea);
  relation["landuse"="industrial"](area.searchArea);
);
out body;
>;
out skel qt;

now i am trying to get the building in that area. (all buildings no matter the tags)

[out:json];
area["name"="my_area"]->.searchArea;
(
  way["landuse"="industrial"](area.searchArea)["building"];
  relation["landuse"="industrial"](area.searchArea)["building"];
);
out body;
>;
out skel qt;

but this does only return buildings that have the tag "landuse"="industrial"? I want all buildings with the general area has "landuse"="industrial". (buildings can have any tags)

Answer 1

The correct solution is a bit more involved, because you need to convert relations explicitly into an internal representation called area (this happens implicitly for ways).

// fetch both ways and relations with landuse=industrial in your current bbox
wr["landuse"="industrial"]({{bbox}});

// visualize landuse=industrial ways and relations for debugging purposes
out geom;

// explicitly convert relation to area, also include ways in search area
map_to_area -> .searchArea;

// query for buildings inside search area
nwr["building"](area.searchArea);

// and print results
out body;
>;
out skel qt;

Note: the query uses the shorter version "wr" for ways & relations, as well as "nwr" for nodes, ways & relations to avoid some extra typing.

Check out this overpass turbo link for an example: https://overpass-turbo.eu/s/1tzE

Sample screenshot highlighting buildings both inside landuse=industrial ways and relations:

Answer 2

You need to save the search area and then do a second query part on the search area. This seems to work, using the bounding-box of the overpass-turbo web site - you may need to change this to your initial area search area.

[out:json][timeout:25];
// gather results
(
  // query part for: “landuse=industrial”
  node["landuse"="industrial"]({{bbox}});
  way["landuse"="industrial"]({{bbox}});
  relation["landuse"="industrial"]({{bbox}});
) -> .searchArea;
// print results
( 
  way["building"](area.searchArea); 
  node["building"](area.searchArea); 
  relation["building"](area.searchArea); 
);
out body;
>;
out skel qt;

For a local industrial area near me I get:

And you can see it is returning buildings, but not the houses in the bounding box (which are also tagged as buildings).

The query for the industrial area alone returns this:

The query text for that being:

[out:json][timeout:25];
// gather results
(
  // query part for: “landuse=industrial”
  node["landuse"="industrial"]({{bbox}});
  way["landuse"="industrial"]({{bbox}});
  relation["landuse"="industrial"]({{bbox}});
) ;
out body;
>;
out skel qt;

All done on http://overpass-turbo.eu/

Confession: I did use ChatGPT to find out how to save the search area and then re-use it, but it took a lot of further crafting to get this solution working. My use of ChatGPT here was no more than using it to find something in a user manual for Overpass. ChatGPT is pretty good at understanding Overpass, which I find very difficult as a human to understand...